@echo Asm5Wav over TEXT Mode is running...
@rem ASM file for PC-MACRO via BASIC-IMG
@rem open console,
@rem change to directory and start batch with "asm5wav FILENAM"
@rem FileToOpen needed: http://www.horstmuc.de/win/wfile.zip

@echo off
if not exist GetFName.cmd (
	%~d0
	cd %~dp0
)
if not exist GetFName.cmd if exist ..\GetFName.cmd cd ..
call SHARPSET
set fnamex=.ASM
set fnamedp=%BASDIR%\
set fnamen=%1
set fnamef=%fnamedp%%fnamen%%fnamex%

Rem Note: Filenames with 1-7 characters are recommended!
if not exist %fnamef% call GetFName %fnamedp% "*%fnamex%;*.BAS;*.PRG;*.ASC;*.SPP;*.SHA;*.shp" "%1"
if not exist %fnamef% (
             echo Error: File %fnamef% does not exist! - Ctrl+C
             goto end
)

set fnamenS=%fnamen:~0,7%
set sharpc1=%SHARPC:~0,1%
set sharpc2=%SHARPC:~0,2%
if "%sharpc1%" == "E"  set fnamenS=%fnamen:~0,8%
if "%sharpc2%" == "G8" set fnamenS=%fnamen:~0,8%
if "%sharpc2%" == "15" set fnamenS=%fnamen:~0,16%
if "%sharpc2%" == "16" set fnamenS=%fnamen:~0,16%
if not "%fnamenS%" == "%fnamen%" (
             echo Note: Filename with less characters is recommended!
             rem goto end
)
set sharpc1=
set sharpc2=

bas2img --type=asm5 --pc=%SHARPC% %fnamef% --auto=5 %BAS2OPT% 
if errorlevel 1 goto end
rem pause
echo.

rem @echo on
bin2wav --type=img --pc=%SHARPC% -d%SHARPDEV% --name=%fnamenS% %fnamedp%%fnamen%.img %WAVDIR%\%fnamen%.wav %BIN2OPT% %2 %3
@echo off
if errorlevel 1 goto end

echo.
echo Start CLOAD and press a key ....
pause
del %fnamedp%%fnamen%.img
start "%fnamen%" %PLAYER% %WAVDIR%\%fnamen%.wav
goto :EOF
:end
pause