@echo AsmCWav over TEXT/BAS Mode is running...
@rem ASM/C file for Pocket assembler via TXT-IMG (E200-G850S: ASC-BAS)
@rem open console,
@rem change to directory and start batch with "asmCwav FILENAM"
@rem FileToOpen needed: http://www.horstmuc.de/win/wfile.zip

@echo off
if not exist GetFName.cmd (
	%~d0
	cd %~dp0
)
if not exist GetFName.cmd if exist ..\GetFName.cmd cd ..
call SHARPSET
set fnamex=.ASM
set fnamedp=%BASDIR%\
set fnamen=%1
set fnamef=%fnamedp%%fnamen%%fnamex%

Rem Note: Filenames with 1-7 characters are recommended!
if not exist %fnamef% call GetFName %fnamedp% "*%fnamex%;*.C;*.ASC;*.BAS" "%1"
if not exist %fnamef% (
             echo Error: File %fnamef% does not exist! - Ctrl+C
             goto end
)

set fnamenS=%fnamen:~0,7%
set sharpc1=%SHARPC:~0,1%
set sharpc2=%SHARPC:~0,2%
if "%sharpc1%" == "E"  set fnamenS=%fnamen:~0,8%
if "%sharpc2%" == "G8" set fnamenS=%fnamen:~0,8%
if "%sharpc2%" == "15" set fnamenS=%fnamen:~0,16%
if "%sharpc2%" == "16" set fnamenS=%fnamen:~0,16%
if not "%fnamenS%" == "%fnamen%" (
             echo Note: Filename with less characters is recommended!
             rem goto end
)
set sharpc1=
set sharpc2=

bas2img --type=%fnamex:~1,4% --pc=%SHARPC% %fnamef% %TEMP%\%fnamen%.tmp %BAS2OPT% 
if errorlevel 1 goto end
rem pause
echo.

rem @echo on
bin2wav --type=asm --pc=%SHARPC% -d%SHARPDEV% --name=%fnamenS% %TEMP%\%fnamen%.tmp %WAVDIR%\%fnamen%.wav %BIN2OPT% %2 %3
@echo off
if errorlevel 1 goto end

echo.
echo Start Text Editor Cmt, BLOAD or CLOAD '%fnamenS%' and press a key ....
pause
start "%fnamen%" %PLAYER% %WAVDIR%\%fnamen%.wav
del %TEMP%\%fnamen%.tmp
goto :EOF
:end
pause