@echo Def2Wav is running...
@rem open console,
@rem change to directory and start batch with "rsv2wav FILENAM"
@rem FileToOpen needed: http://www.horstmuc.de/win/wfile.zip

@echo off
if not exist GetFName.cmd (
	%~d0
	cd %~dp0
)
if not exist GetFName.cmd if exist ..\GetFName.cmd cd ..
call SHARPSET
set fnamex=.DEF
set fnamedp=%BASDIR%\
set fnamen=%1
set fnamef=%fnamedp%%fnamen%%fnamex%

Rem Note: Filenames with 1-7 characters are recommended!
if not exist %fnamef% call GetFName %fnamedp% "*%fnamex%;*.RSV;*.IMG" "%1"
if not exist %fnamef% (
             echo Error: File %fnamef% does not exist! - Ctrl+C
             goto end
)

set fnamenS=%fnamen:~0,7%
set sharpc1=%SHARPC:~0,1%
set sharpc2=%SHARPC:~0,2%
if "%sharpc1%" == "E"  set fnamenS=%fnamen:~0,8%
if "%sharpc2%" == "G8" set fnamenS=%fnamen:~0,8%
if "%sharpc2%" == "15" set fnamenS=%fnamen:~0,16%
if "%sharpc2%" == "16" set fnamenS=%fnamen:~0,16%
if not "%fnamenS%" == "%fnamen%" (
             echo Note: Filename with less characters is recommended!
             rem goto end
)
set sharpc1=
set sharpc2=

REM Load address
if exist %fnamedp%%fnamen%.ADR (
		set /p ADDR=<%fnamedp%%fnamen%.ADR
) else (
        set ADDR=
)
if not "%ADDR%"=="" set ADDR=--addr=%ADDR%

REM PC-1500 or newer Entry word
 if exist %fnamedp%%fnamen%.CAL (
		set /p ADDR2=<%fnamedp%%fnamen%.CAL
 ) 
 if not "%ADDR2%"=="" (
		if not "%ADDR%"=="" set ADDR=%ADDR% --addr=%ADDR2%
 )
set ADDR2=

rem @echo on
bin2wav --type=def --pc=%SHARPC% -d%SHARPDEV% --name=%fnamenS% %ADDR% %fnamef% %WAVDIR%\%fnamen%.wav %BIN2OPT% %2 %3

@echo off

if errorlevel 1 goto end

echo.
echo Start the Software, that need this ....
pause
start "%fnamen%" %PLAYER% %WAVDIR%\%fnamen%.wav
goto :EOF
:end
pause